
Often we must run similar SAS code many times.  For example, we might run a similar analysis on several different independent variables or we might want to read in several data files and then concatenate or merge them together into one large data set.

An obvious solution is to copy the code as many times as necessary and change a few variable and/or dataset names.  But this can be onerous to do, leads to tedious and long programs, and increases the chances of typing mistakes.  Another solution is to set up a simple macro with a few macro variables to represent the changing variable and/or data set names and then run the macro many times.  

Basic Macro Programming  - The basic form of the macro programming is:

%macro macroname; - starts the macro, giving the name for the macro.
SAS programming code including macro variables.  These variables are denoted by an ‘&’ and may end in a ‘.’ if there might be any ambiguity about where the name of the macro variables ends.   Example: &macrovar.  

%mend; or  %mend macroname; - ends the macro, the macroname is optional. 

%let macrovar = text values; - Defines the value to be used for the macro variable.
-  Macro variables are identified within SAS code by a prefix of ‘&’.
-  The values are treated as text.  Working with numbers as numbers requires
   additional macro statements and functions.
-  Macro variables inside quotes must be inside double quotes to be resolved properly.  
-  Macro variables retain their value until assigned a new value.  
-  A null value will be assigned if there is no text after the equals sign.
-  Macro variables will work outside of defined macros.

%macroname; - calls the macro and runs the code after resolving any macro variables within the macro.
Macro statements can be identified by the fact that they start with a percent (%) sign.  SAS has several manuals that discuss macro programming in considerable detail including, of course, the other macro statements available for use.

Example 1: Producing printer plots for different pairs of variables

As a simple example, suppose that several plots of various y-variables are to be plotted against several x-variables.  The following program will plot yvar versus xvar using the first digit of the  treat values as the plotting symbol.  The names of the variables are included in a title statement so that they will appear at the top of the printout (but only if double quotes are used around the title!). 

/** Macro for plotting pairs of variables **/
%macro plots;                       *<< Starting the macro definition;

title "For &yvar against &xvar";    *<< Must use double quotes!;

proc plot; 

  plot &yvar*&xvar = treat; run;

%mend;                              *<< Macro end;
** Calling the macro many times;
%let yvar = y1; %let xvar = y2;  %plots; *<< plots y1 vs y2;
                %let xvar = x1;  %plots; *<< plots y1 vs x1;
%let yvar = y2;                  %plots; *<< plots y2 vs x1;
The programming after the macro definition first defines yvar to be y1 and xvar to be y2 and then runs the plots macro for these two variables.  Then y1 is plotted against x1 and lastly y2 is plotted against x1.

An advantage of using macros in this way is that it is easy to see what runs have been done.  For instance, you may have also wanted to plot x1 vs x2 and it is easy to see from the above code that you haven’t asked for that plot.

Example 2: Producing printer plots for different subsets of the data

Suppose that we want to produce plots as in example 1, but we want to do this for subsets of the data.  For example, we might want plots of y1 vs y2 for zones 2 and 3, but a plot of y1 vs x1 for zones 3, 4 and 5.  We can add another macro variable to use in a where statement.

/** Macro for plotting pairs of variables **/
%macro plots;                         *<< Starting the macro definition;
title  "For &yvar against &xvar";     *<< Must use double quotes!;
title2 "For zones: &zonevals";        *<< Must use double quotes!;

proc plot; where zone in(&zonevals); * by zone;
  plot &yvar*&xvar = treat; run;

%mend plots;

** Calling the macro many times;
%let yvar = y1; %let xvar = y2;  %let zonevals = 2,3;    %plots; 

                %let xvar = x1;  %let zonevals = 3 4 5;  %plots;
If we wanted separate plots for each zone within each group, we could remove the commenting ‘*’ in front of the by statement.

Example 3: Running an ANOVA for several dependent variables

We often want to do the same analysis for several dependent variables.  We could do this for an ANOVA by simply listing the variables in the model statement on the left side of the equals sign.  But usually we also want to output the residuals and predicted values to plot the data and check that the residuals look suitably random.  The output statement requires a separate variable name for the residuals and predicted values for each independent variable.  This can be a lot of variable names!  Instead it may be easier to prepare a macro and then cycle through it for each dependent variable.

The following split-plot ANOVA is a little unusual in its design: blocks are nested within zone and each treatment occurs within each block.  The dataset contains just one value for each treatment plot within the blocks so that there is no subsample data.  Each page of output lists the dependent variable being analysed in the title.

/** Macro to do ANOVA for several dependent variables **/
%macro analysis;

title2 "Using GLM for the analysis";  

title3 "For variable &yvar";

proc glm;

  class zone block treat;  

  model &yvar = zone block(zone) treat zone*treat;

  test h = zone e = block(zone);

  contrast 'Treat: Linear' treat -1  0  1;

  contrast 'Treat: Quad'   treat  1 -2  1;

  lsmeans zone / stderr e=block(zone); 

  lsmeans treat zone*treat / stderr;

  output out = resid p=pred r=resid;

run; 

proc plot data=resid; 

  plot resid*pred = treat resid*treat = zone / vref = 0; 

run;

proc sort data=resid; by zone treat; run;

proc univariate plot normal data=resid;

  by zone treat; var &yvar; 

run;

%mend;

** Calling the macro many times;
%let yvar = y1;  %analysis;

%let yvar = y2;  %analysis;

%let yvar = y3;  %analysis; 

Example 4: Regression analysis with different independent variables

When studying a multiple regression, it is often of interest to consider models with different groups of independent variables.  I prefer to first look at all possible models with a model option such as selection = cp or selection = adjrsq so that I have a better chance of finding the “best” model
.  But there is often a subset of models from this list that are of interest and whose residuals I would like to examine using plots before deciding upon a final model.

The following macro makes it easy to fit different groups of independent variables and plot the residuals using the plotting options within proc reg.  These plots will appear in the graphics window of SAS and can be examined there - setting them up for publication or inclusion into WORD documents is beyond the limits of the current discussion.

The following code assumes that a plot of the data with fitted values against one of the independent variables is of interest and useful – it might not be in a multiple regression situation.  But it does allow us to use a macro variable within a macro variable.  The firstxvar macro variable is used to define the variable used for this plot.  Then xvar is used to list all the variables to be included in the model for that run.

/** Macro to run regression analyses with varying independent variables  **/
%macro regr;

title "Regression between &yvar and &xvar";

proc reg data=test;

model &yvar = &xvar ;

  plot residual.*predicted. / vref=0;

  plot &yvar*&firstxvar  predicted.*&firstxvar='*' / overlay;

run; quit;

%mend regr;

** Calling the macro many times;
%let yvar = y1; %let firstxvar = x1 ; %let xvar = &firstxvar x2 x3;   %regr; 

                                      %let xvar = &firstxvar x2   ;   %regr; 

                %let firstxvar = x2 ; %let xvar = &firstxvar x1   ;   %regr; 

A model with x1, x2, and x3 is fit first.  Then a model with just x1 and x2 is fit.  The third run simply switches the roles of x1 and x2 for the plot of fitted values.

Example 5: Reading in many tables from an ACCESS database

In this example, we want to convert data from a number of tables in an ACCESS database into permanent SAS datasets.  First, I used the import data wizard in the file drop-down menu to import the first table and obtain the required SAS code.  Then I created a macro around that program so that I could run it again for each table I wanted to import.  Since the data in the ACCESS database frequently changed as errors were found during the analysis, the macro import program allowed a speedy recreation of the SAS datasets for further work.  Notice that the SAS dataset names are the same as the original table names in the ACCESS database.  I could have used a second macro variable to give the new SAS datasets names different from the table names in the ACCESS database.

/** Importing individual tables from Access Database **/
libname wildlife "H:\Projects\Wildlife Trees\Data";

%macro import;

PROC IMPORT OUT= WILDLIFE.&name DBMS=ACCESS97 REPLACE 

  DATATABLE= "&name";

  DATABASE="H:\Projects\WildlifeTrees\Data\wtppdb1f_d5.mdb"; 

RUN;

%mend;

** Calling the macro many times;
%let name = AppCompInfo;                 %import;

%let name = block;                       %import;

%let name = plot;                        %import;

%let name = reserve;                     %import;

%let name = reserveDetail;               %import;

%let name = reserveSample;               %import;

%let name = reserveTree;                 %import;

%let name = sample;                      %import;

%let name = tree;                        %import;
Example 6: Reading in many data files and concatenating into one large SAS dataset

We often want to import data from several files and concatenate them together into one complete data set for analysis.  A common example of this is when data collected for each year and/or site have been put into individual ASCII files or EXCEL spreadsheets.  A macro that allows us to import each file and concatenate it into a large dataset would be very useful in this situation.

In this example, we will import data from several ASCII files that are in CSV format.  They were exported from EXCEL into this format.  As we read each file in, we concatenate it with previous imports into a dataset called ALL.  The trick here is that the code for creating ALL from the first file imported is different than for the following files.  To do this, we need some new macro commands: %IF, %DO, %THEN, %END, and %ELSE.  These behave just like those familiar SAS statements without percent signs used in regular data step programming.

The first part of the macro readin is simply the data step to read in the file.  In this case, some of the files have the variable regen and some do not.  So the macro variable inpt is used to include the variable in the input statement when it occurs and leave it out, with a null string, when it does not.

The macro variable flag is used to choose between the next two sets of SAS code defined by the %DO and %END statements.  For the first data set the flag is set to 1, and the code to start the creation of dataset ALL is run.  For following datasets, the second set of code is used to add the most recently imported dataset to the growing complete dataset ALL. The %IF, %THEN, and %ELSE macro statements do the switching, while the %DO and %END statements define which SAS code is to be run.  

/** Reading in data files and concatenating into one SAS dataset **/
%macro readin;

data &dsn;

  infile "&inf" DLM = ',' dsd firstobs = 2 missover;

  input inst $ blk plt splt can &inpt lay $ spp $ percov modht ;

run;

%if &flag = 1 %then %do; *<< First data set read in;
   data all; set &dsn;     run; %end;

%else %do;               *<< All subsequent data sets read in;
   data all; set all &dsn; run; %end;

%mend;

** Calling the macro many times;
%let flag = 1;   *<< For first data set;
%let dsn = b1a; %let inf = aaa.csv; %let inpt = ;         %readin;

%let flag = 2;   *<< For all subsequent data sets;
%let dsn = b1b; %let inf = bbb.csv; %let inpt = regen $;  %readin;

%let dsn = b1c; %let inf = ccc.csv; %let inpt = ;         %readin;
%let dsn = b1d; %let inf = ddd.csv; %let inpt = regen $ ; %readin;
This program would use less hard drive space if the dataset name (macro variable dsn) remained the same for each file read in.  If the proposed analysis will be done on only the final and complete ALL dataset, the intermediate datasets do not need to be kept and can simply be replaced during each invocation of the macro.

Dealing with errors

Finding and fixing errors with a macro can be tricky.  When the macro runs, it does not show all of the SAS code in the log.  Nevertheless, notes about the completion of data steps and procedures are displayed in the log along with any error messages.  The following are some simple things that I do to track down errors.  The SAS manuals and help files contain considerably more information.

1) Build the macro code slowly in small pieces and/or run the code first as ordinary SAS code without defining a complete macro.  This may not be possible if you need to use macro statements such as %IF and %DO which only work inside of defined macros.

2) Use a %PUT statement to print values of macro variables to the SAS log.  This way you can check to see if the values are being substituted correctly.  You can also do this to monitor the progress of a long running job.  As an example, let’s add a %PUT statement to the readin macro of the previous example:
/** Reading in data files and concatenating into one SAS dataset **/
%macro readin;

%put *******  Now working on file: &inf to create &dsn dataset *******;

data &dsn;

  infile "&inf" DLM = ',' dsd firstobs = 2 missover;

  input inst $ blk plt splt can &inpt lay $ spp $ percov modht ;

run;

%if &flag = 1 %then %do; *<< First data set read in;
   data all; set &dsn;     run; %end;

%else %do;               *<< All subsequent data sets read in;
   data all; set all &dsn; run; %end;

%mend;

The asterisks in the %PUT statement make the line more visible in the SAS Log file.

You can also output a list current values of all the macro variables you have defined since starting up SAS by using the following option in the %PUT statement:

%put  _user_; 

3) Use SAS options designed to help debug macros.  Two that may be useful are listed below.  Note that either of these options can greatly lengthen the SAS log!


· SYMBOLGEN – writes to the log the values of the macro variables as the program is run.

· MPRINT – writes to the log the SAS statements as they are generated by the macro.

These options are turned on by: 
options   mprint   symbolgen;
and turned off by:
options nomprint nosymbolgen;
These options statements can be placed anywhere in the SAS program

� See Biometrics Information Pamphlet #18 for a statistical discussion of this.

